1.1.2 Aantal contractuele FTE personeel in loondienst (PIL) zonder zorgfunctie op 1 januari

Concepten

• Arbeidsovereenkomst
• Contractomvang
• Contractomvangwaarde
• Functie in organisatie-rol
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft meeteenheid
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• FTE (36 uur per week)

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: NZA Wmg 1.1.2
2# Parameters: ?jaar
3# Ontologie: versie 3.0
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12    (SUM(?fte) AS ?Teller)
13    ("Niet van toepassing" AS ?Noemer)
14    (?Teller AS ?Indicator_FTE36)
15WHERE {
16    {
17        SELECT 
18            ?overeenkomst_afspraak
19        WHERE {
20            # BIND(2024 AS ?jaar) .  # Parameter
21
22            BIND(STRDT(CONCAT(STR(?jaar), "-01-01"), xsd:date) AS ?peildatum) .
23
24            ?overeenkomst 
25                a onz-pers:ArbeidsOvereenkomst ; # personeel in loondienst
26                onz-pers:heeftOpdrachtnemer ?persoon ;
27                onz-g:hasPart ?overeenkomst_afspraak .
28
29            ?overeenkomst_afspraak
30                a onz-pers:WerkOvereenkomstAfspraak ;
31                onz-g:startDatum ?start_afspraak .
32            OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
33            FILTER(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum) || (!BOUND(?eind_afspraak)))) # geldig op peildatum
34
35            ?overeenkomst_afspraak
36                onz-g:isAbout/a ?function_class .
37            ?function_class rdfs:subClassOf onz-g:OccupationalPositionRole .
38            BIND(IF(?function_class = onz-pers:ZorgverlenerFunctie, 1, 0) AS ?zorgverlener) # ?zorgverlener = 1 als afspraak over zorgverlenerfunctie gaat
39        }
40        GROUP BY ?overeenkomst_afspraak
41        HAVING (MAX(?zorgverlener) = 0) # neem max van ?zorgverlener omdat er dubbele regels voor kunnen komen (OccupationalPostionRole EN ZorgverlenerFunctie)
42                                        # filter zodat alleen niet-zorgverleners overblijven
43    }
44    ?overeenkomst_afspraak onz-g:hasPart ?omvang . # haal omvang van alle geldige afspraken op
45    ?omvang 
46        a onz-pers:ContractOmvang ;
47        onz-g:isAbout ?omvang_waarde .
48
49    ?omvang_waarde
50        a onz-pers:ContractOmvangWaarde ;
51        onz-g:hasDataValue ?omvang_waarde_getal ;
52        onz-g:hasUnitOfMeasure ?omvang_waarde_eenheid .
53    ?omvang_waarde_eenheid onz-g:hasDataValue ?eenheid_factor .
54    BIND(IF(?omvang_waarde_eenheid = onz-pers:fte_36, ?omvang_waarde_getal, ?omvang_waarde_getal / 36 * ?eenheid_factor) AS ?fte) # omrekenen naar fte_36
55}
56